Chapter 3, Section 3.7, Figure 3.12

We start by defining α as in Eq.(3.75).

α = (μ/(3*(1-μ)))^(1/3);

Use the series given in Eq.(3.83) to find the radial distance to the second body, r2,  as a function of α.

r2 = α - (1/3)*α^2 - (1/9)*α^3 - (23/81)*α^4;

At the L1 point the distance to the first body, r1, is just 1-r2.

r1 = 1-r2;

Define abar as in Eq.(3.128) and express it as a series in μ.

abar = N[Normal[Series[(1-μ)/r1^3 + μ/r2^3, {μ,0,1}]]]

Set up the characteristic equation, ce.

ce = λ^4+(2-abar)*λ^2+(1+abar-2*abar^2)==0;

Calculate the four roots of the characteristic equation for mass ratios between 0.1 and 0.001.  Express each root in terms of its real and imaginary part and store in a list.

pts = 
Table[Map[ {Re[#], Im[#]}&, 
(λ /. N[Solve[(ce /. μ -> tμ),λ]])],
     {tμ,0.1,0.001,-0.0002}];

For example, here are the four roots for μ=0.1.  Notice the pattern in the roots.

pts[[1]]

Transpose the results for future use ...

tpts = Transpose[pts];

... and check on the dimensions.

Dimensions[pts]

Set up a list of the corresponding masses.  Note that we take the negative of the logarithm in order to have the mass decreasing from left to right.

mass = Table[-Log[10,i], {i,0.1,0.001,-0.0002}];

We plot the real parts of the first roots for all the masses.  These are non-zero.

p11 = ListPlot[Transpose[{mass,Transpose[tpts[[1]]][[1]]}],
        PlotJoined->True]

Then we plot the imaginary parts of the first roots.  These are all zero. (See the pts[[1]] example above.)

p12 = ListPlot[Transpose[{mass,Transpose[tpts[[1]]][[2]]}],
        PlotJoined->True,PlotStyle->{Dashing[{0.02,0.02}]}]

Then we plot the real parts of the second roots.  These are all zero. (See the pts[[1]] example above.)

p21 = ListPlot[Transpose[{mass,Transpose[tpts[[2]]][[1]]}],
        PlotJoined->True]

Then we plot the imaginary parts of the second roots.  These are non-zero. (See the pts[[1]] example above.)

p22 = ListPlot[Transpose[{mass,Transpose[tpts[[2]]][[2]]}],
        PlotJoined->True,
        PlotStyle->{Dashing[{0.02,0.02}]}]

Then we plot the real parts of the third roots.  These are all zero. (See the pts[[1]] example above.)

p31 = ListPlot[Transpose[{mass,Transpose[tpts[[3]]][[1]]}],
        PlotJoined->True]

Then we plot the imaginary parts of the third roots.  These are non-zero. (See the pts[[1]] example above.)

p32 = ListPlot[Transpose[{mass,Transpose[tpts[[3]]][[2]]}],
        PlotJoined->True,
        PlotStyle->{Dashing[{0.02,0.02}]}]

Then we plot the real parts of the fourth roots.  These are non-zero. (See the pts[[1]] example above.)

p41 = ListPlot[Transpose[{mass,Transpose[tpts[[4]]][[1]]}],
        PlotJoined->True]

Finally we plot the imaginary parts of the fourth roots.  These are all zero. (See the pts[[1]] example above.)

p42 = ListPlot[Transpose[{mass,Transpose[tpts[[4]]][[2]]}],
        PlotJoined->True,
        PlotStyle->{Dashing[{0.02,0.02}]}]

We can put these all together in one plot.  Here the solid and dashed lines denote the real and imaginary parts respectively.  This shows that the nature of the roots does not change as the mass decreases.

Show[p11,p22,p32,p31,p41,
     PlotRange->{{1,3},{-3.5,3.5}},
     Frame->True,AxesOrigin->{1,-3.5}]