Chapter 3, Section 3.9, Figure 3.17

Set the mass ratio, μ, in keeping with Taylor's (1981) value.

μ = 0.000953875;
μ1 = 1 - μ;
μ2 = μ;

Create a graphics object to represent the locations of both masses and the L4 and L5 points.

masses = 
Graphics[
 {{PointSize[0.02], Point[{ μ1, 0}]},
  {PointSize[0.04], Point[{-μ2, 0}]},
  {PointSize[0.01], Point[{0.5-μ2,N[Sqrt[3]/2]}]},
  {PointSize[0.01], Point[{0.5-μ2,-N[Sqrt[3]/2]}]}}];

Define a function ThreeBodyOrbit that solves for the trajectory of the particle in the planar, circular restricted problem.

ThreeBodyOrbit[{x0_, y0_, xd0_, yd0_}, tmax_, 
                ppoints_:100, maxsteps_:1000] :=
Module[{sol},
  sol = NDSolve[
  {x''[t]-2*y'[t] ==  
    x[t] - μ1*(x[t]+μ2)/(Sqrt[(x[t]+μ2)^2+y[t]^2]^3) -
           μ2*(x[t]-μ1)/(Sqrt[(x[t]-μ1)^2+y[t]^2]^3),
   y''[t]+2*x'[t] == 
    y[t] - (μ1/(Sqrt[(x[t]+μ2)^2+y[t]^2]^3) +
            μ2/(Sqrt[(x[t]-μ1)^2+y[t]^2]^3))*y[t],
   x[0]==x0, y[0]==y0, x'[0]==xd0, y'[0]==yd0},
   {x,y}, {t,0,tmax}, MaxSteps->maxsteps];
  ParametricPlot[Evaluate[{x[t],y[t]} /. sol],
                 {t,0,tmax}, 
                 PlotRange->All, 
                 AspectRatio->Automatic,
                 PlotPoints->ppoints]
]

Define all of Taylor's staring conditions.  In fact, we will only make use of taylor3 and taylor4.

taylor1 = {-0.11239, 0.0, 0.0, -4.00533};
taylor2 = {-1.06201, 0.0, 0.0,  0.10851};
taylor3 = {-1.02745, 0.0, 0.0,  0.04032};
taylor4 = {-0.97668, 0.0, 0.0, -0.06118};
taylor5 = {-0.76665, 0.0, 0.0, -0.51230};
taylor6 = {-0.42413, 0.0, 0.0, -1.51123};

Integrate the orbit for the taylor3 starting values.

horset3 =
ThreeBodyOrbit[taylor3, 60Pi]

Add the masses and L4 and L5 points to the plot.

pht3 = 
Show[horset3, masses, 
 AspectRatio->Automatic, Axes->None]

Integrate the orbit for the taylor4 starting values.

horset4 =
ThreeBodyOrbit[taylor4, 60Pi, 100, 1500]

Add the masses and L4 and L5 points to the plot.

pht4 = 
Show[horset4, masses, 
 AspectRatio->Automatic, Axes->None]

Display both plots together.

Show[GraphicsArray[{pht4, pht3}]]