Chapter 3, Section 3.6

We start by defining the mass ratio in terms of r1, r2 and their derivatives with respect to x.  Remember that all the collinear points have y=0.

μratio = 
((-1/r1^2 + r1)*dr1dx) / ((-1/r2^2+r2)*dr2dx)

For the L1 point (Subscript[r, 1])=1–(Subscript[r, 2]), d(Subscript[r, 1])/dx=1 and d(Subscript[r, 2])/dx=1 and so the expression for the mass ratio becomes (see Eq.(3.74)):

rat1 = 
Simplify[Expand[(μratio /. 
{r1 -> 1-r2, dr1dx -> 1, dr2dx -> 1})*r2^3]]/r2^3

Now we divide by 3 and take the cube root (see Eq.(3.75)) to get an expression for α.

tα1 = (rat1/3)^(1/3)

Expand this to get a series for α in terms of (Subscript[r, 2])(see Eq.(3.76)).

αser1= Series[tα1,{r2,0,4}]

Finally, we invert this series using InverseSeries to get the series for (Subscript[r, 2]) in terms of α (see Eq.(3.83)).

r21 = InverseSeries[αser1, α]

Now we repeat the same procedure for the L2 point.  At this point  (Subscript[r, 1])=1+(Subscript[r, 2]), d(Subscript[r, 1])/dx=1 and d(Subscript[r, 2])/dx=1 and so the expression for the mass ratio becomes (see Eq.(3.86)):

rat2 = 
Simplify[Expand[(-μratio /. 
{r1 -> 1+r2, dr1dx -> 1, dr2dx -> 1})*r2^3]]/r2^3

Now we divide by 3 and take the cube root to get an expression for α.

tα2 = (rat2/3)^(1/3)

Expand this to get a series for α in terms of (Subscript[r, 2])(see Eq.(3.87)).

αser2 = Series[tα2,{r2,0,4}]

Finally, we invert this series using InverseSeries to get the series for (Subscript[r, 2]) in terms of α (see Eq.(3.88)).

r22 = InverseSeries[αser2, α]

The situation is slightly different for calculating the series for the L3 point.  At this point (Subscript[r, 2])=1+(Subscript[r, 1]), d(Subscript[r, 1])/dx=–1 and d(Subscript[r, 2])/dx=–1 and so the expression for the mass ratio becomes (see Eq.(3.91)):

rat3 = 
Simplify[Expand[(-μratio /. 
{r2 -> 1+r1, dr1dx -> -1, dr2dx -> -1})*r2^3]]/r2^3

Now we take this ratio and evaluate it when (Subscript[r, 1])= 1+β.

rat3b = rat3 /. {r1 -> 1+β}

We expand this to get the series for (Subscript[μ, 2])/(Subscript[μ, 1])in terms of β (see Eq.(3.92)).

rat3c = Series[rat3b,{β,0,3}]

Finally we invert this series to get β as a series in (Subscript[μ, 2])/(Subscript[μ, 1])(see Eq.(3.93)).

βs = InverseSeries[rat3c, μrat] /. μrat->(μ2/μ1)