Chapter 10, Section 10.2, Figure 10.1

We start by defining the radii, jring, of the principal rings of Jupiter.

jring = {1.3, 1.72, 1.81, 3};

Next we define semi-major axes, jsat, of the satellites of Jupiter.

jsat = N[{127960, 128980, 181300, 221900}/71492]

Now define the orbital radius, jsync, of the synchronous orbit of Jupiter.

jsync = Graphics[{Dashing[{0.02,0.02}],
               Circle[{0,0},2.3,{3Pi/4,Pi}]}];

Do the same definitions for the Saturn system.

sring = {1.11, 1.24, 1.52, 1.95, 2.02, 2.27, 2.324,
         2.75, 2.88, 3.59, 5.11};

ssat = N[{133595, 137640, 139350, 141700, 151422, 151472,
        185520, 238020, 294660}/60268]

ssync = Graphics[{Dashing[{0.02,0.02}],
               Circle[{0,0},1.89,{Pi/2,3Pi/4}]}];

Do the same definitions for the Uranus system.

uring = {1.49, 1.597, 1.612, 1.625, 1.707, 1.743, 
         1.801, 1.818, 1.843, 1.909, 1.952};

usat = N[{49750, 53760, 59160, 61770, 62660, 64360,
          66100, 69930, 75260, 86010, 129780}/25559]

usync = Graphics[{Dashing[{0.02,0.02}],
               Circle[{0,0},3.22,{Pi/4,Pi/2}]}];

Do the same definitions for the Neptune system.

nring = {1.69, 2.15, 2.4, 2.53};

nsat = N[{48000, 50000, 52500, 62000, 73600, 117600}/24764]

nsync = Graphics[{Dashing[{0.02,0.02}],
               Circle[{0,0},3.44,{0,Pi/4}]}];

Create a graphics object for the semi-circle denoting the surface of the generic planet at unit radius.

planet = Graphics[Circle[{0,0},1,{0,Pi}]];

Create graphics objects for the rings and satellites of each planet.

jr = Graphics[Map[Circle[{0,0},#,{3Pi/4,Pi}]&,jring]];

js = Graphics[{Dashing[{0.01,0.01}],
               Map[Circle[{0,0},#,{3Pi/4,Pi}]&,jsat]}];

sr = Graphics[Map[Circle[{0,0},#,{Pi/2,3Pi/4}]&,sring]];

ss = Graphics[{Dashing[{0.01,0.01}],
               Map[Circle[{0,0},#,{Pi/2,3Pi/4}]&,ssat]}];

ur = Graphics[Map[Circle[{0,0},#,{Pi/4,Pi/2}]&,uring]];

us = Graphics[{Dashing[{0.01,0.01}],
               Map[Circle[{0,0},#,{Pi/4,Pi/2}]&,usat]}];

nr = Graphics[Map[Circle[{0,0},#,{0,Pi/4}]&,nring]];

ns = Graphics[{Dashing[{0.01,0.01}],
               Map[Circle[{0,0},#,{0,Pi/4}]&,nsat]}];

Add the separating lines.

lines = Graphics[{
Line[{{Cos[Pi/4],Sin[Pi/4]},5.5*{Cos[Pi/4],Sin[Pi/4]}}],
Line[{{0,1},{0,5.5}}],
Line[{{Cos[3Pi/4],Sin[3Pi/4]},5.5*{Cos[3Pi/4],Sin[3Pi/4]}}],
Line[{{-5,0},{5,0}}]}]

Create a graphics object to denote the centre of the planet.

dot = Graphics[Circle[{0,0},0.05,{0,Pi}]]

Display the ring orbits.

rings = Show[planet,jr,sr,ur,nr,lines,dot,
     AspectRatio->Automatic,PlotRange->All]

Display the satellite orbits.

sats = Show[planet,js,ss,us,ns,lines,dot,
     AspectRatio->Automatic,PlotRange->All]

Display the ring, satellite and synchronous orbits (see Fig.10.1).

Show[planet,jr,js,sr,ss,ur,us,nr,ns,
     jsync,ssync,usync,nsync,lines,dot,
AspectRatio->Automatic,PlotRange->All]