Chapter 4, Section 4.6

Equation (4.115) is rewritten to express σ/⟨ρ⟩ as a function of \(TraditionalForm\`C\&_\) and r = A/B.  We do this by defining a function σρ.

σρ[C_, r_] := 
      1/(1 - (1/
                  r^3)*(1 - (5/2)*C)/(r^2 - (5/2)*
                      C))

Define δ to be a function of r = A/B and sr = σ/ρ.

δ[r_, sr_]  :=  r^3*(1 - sr)

Then define γ to be a function of sr = σ/ρ.

γ[sr_] :=  (2/5) + (3/5)*sr

Now we are in a position to define the function J2f that returns the value of (Subscript[J, 2])/f  for specified values of \(TraditionalForm\`C\&_\) and r = A/B.

J2f[C_, 
        r_] := (2/
            3) + (C - (2/5)*r^2)/(1 - r^2) - (2/
              3)/(1 + (3/5)*δ[
                    r, σρ[C, r]]/γ[σρ[C, r]]*
                r^2)

The Darwin-Radau relation is an approximation to (Subscript[J, 2])/f  that is valid in the limit as r → 1.  We can show this by starting with an expression for (Subscript[J, 2])/f  for general values of \(TraditionalForm\`C\&_\) and A/B.

temp = J2f[C, r]

This can be simplified somewhat.

stemp = Simplify[temp]

Now take the limit of this expression as r → 1.  This gives the same expression as Eq.(4.114).

Limit[stemp, r -> 1]

Use this to define a function DarwinRadau.

DarwinRadau[C_]:=N[(-3/10)+(5/2)C-(15/8)C^2]

Plot the straight line for the point-core model where r → 0.

pcm = 
      ListPlot[Table[{cval, cval}, {cval, 0, 0.4, 0.001}], 
        PlotJoined -> True]

Plot J2f as a function of \(TraditionalForm\`C\&_\) for a model with r = 0.5.

r05 = 
      ListPlot[Table[{cval, J2f[cval, 0.5]}, {cval, 0.0001, 0.4, 0.001}], 
        PlotJoined -> True]

Plot J2f as a function of \(TraditionalForm\`C\&_\) for a model with r=0.99.  This should be close to the Darwin-Radau relation.

r99 = 
      ListPlot[Table[{cval, J2f[cval, 0.99]}, {cval, 0, 0.4, 0.001}], 
        PlotJoined -> True]

Plot J2f as a function of \(TraditionalForm\`C\&_\) for the Darwin-Radau model.

dr = 
      ListPlot[Table[{cval, DarwinRadau[cval]}, {cval, 0, 0.4, 0.001}], 
        PlotJoined -> True]

Compare the r=0.99 plot with the Darwin-Radau model plot.  They are almost identical.

Show[r99, dr,  Frame -> True,  PlotRange -> {{0, 0.4}, {0, 0.4}}, 
      AspectRatio -> 1]

Plot the Darwin-Radau approximation together with the r=0.5 plaot and the point-core model for comparison.

Show[dr,r05,pcm,Frame->True, 
PlotRange->{{0,0.4},{0,0.4}},AspectRatio->1]