Chapter 8, Section 8.12, Figures 8.25–28

The definitions of the following functions are taken from the PhD thesis of Malhotra (1988).

First we consider first-order resonances and define the functions ψ, Φ1, Φ2, Φ3, Φmin, Φmax and γ.

ψ[δ_] := N[ArcTan[Sqrt[(δ+1)^3-1]]];

Φ1[δ_] := N[2*(δ+1)*Cos[ψ[δ]/3]^2];

Φ2[δ_] := N[(1/2)*(δ+1)*(Cos[ψ[δ]/3]-Sqrt[3]*Sin[ψ[δ]/3])^2];

Φ3[δ_] := N[(1/2)*(δ+1)*(Cos[ψ[δ]/3]+Sqrt[3]*Sin[ψ[δ]/3])^2];

Φmin[δ_] := N[3*(δ+1) - Φ3[δ] - 2*(2*Φ3[δ])^(1/4)];

Φmax[δ_] := N[3*(δ+1) - Φ3[δ] + 2*(2*Φ3[δ])^(1/4)];

γ[δ_] := 
N[ArcSin[(Φmax[δ]+Φmin[δ]-2*Φ3[δ])/(Φmax[δ]-Φmin[δ])]];

Now define the functions to calculate the area enclosed by the outer and inner branches of the separatrix (see Eqs.(8.213) and (8.214).

Areaext[δ_] := N[Abs[
-3*((1/2)*(Φmax[δ] + Φmin[δ] + 2*Φ3[δ] - 2*(δ+1))*
 (Pi/2+γ[δ]) + Sqrt[(Φmax[δ]-Φ3[δ])(Φ3[δ]-Φmin[δ])])]];

Areaint[δ_] := N[Abs[
3*((1/2)*(Φmax[δ] + Φmin[δ] + 2*Φ3[δ] - 2*(δ+1))*
(Pi/2-γ[δ]) - Sqrt[(Φmax[δ]-Φ3[δ])(Φ3[δ]-Φmin[δ])])]];

Define the function that gives the probability of capture (see Eq.(8.220)).

ProbCap[δ_] := N[4*γ[δ]/(Pi+2*γ[δ])];

Plot the area enclosed by the outer branch of the separatrix.

outer1 = Plot[Areaext[δ]/2/Pi,{δ,0,10}]

Plot the area enclosed by the inner branch of the separatrix.

inner1 = Plot[Areaint[δ]/2/Pi,{δ,0,10}]

Show both plots together (see Fig.8.25).

areas1 = Show[outer1,inner1,
     Frame->True,PlotRange->{{0,10},{0,20}}]

Now do the plot of probability of capture as a function of the value of δ at transition (see Fig.8.26).

prob1 = Plot[ProbCap[δ],{δ,0,10},
  Frame->True,
  PlotRange->{{0,10},{0,1}}]

Now we consider second-order resonances and define the functions ψ, Φ1, Φ2, Φ3, Φmin, Φmax and γ.

Φ1[δ_] := (1/2)*(1+δ);

Φ2[δ_] := 0;

Φ3[δ_] := (1/2)*δ;

Φmin[δ_] := (1/2)*(1+δ) - (1/2)*Sqrt[1+2*δ];

Φmax[δ_] := (1/2)*(1+δ) + (1/2)*Sqrt[1+2*δ];

γ[δ_] := ArcSin[(Φmax[δ]+Φmin[δ]-2*Φ3[δ])/(Φmax[δ]-Φmin[δ])];

Now define the functions to calculate the area enclosed by the outer and inner branches of the separatrix (see Eqs.(8.227) and (8.228).

Areaext[δ_] := Abs[
-2*((1/2)*(Φmax[δ] + Φmin[δ] + 2*Φ3[δ])*
 (Pi/2+γ[δ]) + Sqrt[(Φmax[δ]-Φ3[δ])(Φ3[δ]-Φmin[δ])])];

Areaint[δ_] := Abs[
 2*((1/2)*(Φmax[δ] + Φmin[δ] + 2*Φ3[δ])*
(Pi/2-γ[δ]) - Sqrt[(Φmax[δ]-Φ3[δ])(Φ3[δ]-Φmin[δ])])];

Define the function that gives the probability of capture (see Eq.(8.220)).

ProbCap[δ_] := N[4*γ[δ]/(Pi+2*γ[δ])];

Plot the area enclosed by the outer branch of the separatrix.

outer2 = Plot[Areaext[δ]/2/Pi,{δ,0,10}]

Plot the area enclosed by the inner branch of the separatrix.

inner2 = Plot[Areaint[δ]/2/Pi,{δ,0,10}]

Show both plots together (see Fig.8.27).

areas2 = Show[outer2,inner2,
     Frame->True,PlotRange->{{0,10},{0,7}}]

Now do the plot of probability of capture as a function of the value of δ at transition (see Fig.8.28).

prob2 = Plot[ProbCap[δ],{δ,0,10},
  Frame->True,
  PlotRange->{{0,10},{0,1}}]